Queries for the QuantumProviderAccountDeviceOperationLogs table

For information on using these queries in the Azure portal, see Log Analytics tutorial. For the REST API, see Query.

Quantum device operation pass rate (last 6 hours)

Percentage of operations by type that succeeded over the last 6 hours, based on terminal (Succeeded or Failed) records.

// Percentage of device operations that passed (Succeeded) over the last 6 hours.
// Only terminal records (Succeeded or Failed) are counted; Started records are excluded
// so each run is represented by its outcome exactly once.
QuantumProviderAccountDeviceOperationLogs
| where TimeGenerated > ago(6h)
| where ResultType in ("Succeeded", "Failed")
| summarize Total = count(), Passed = countif(ResultType == "Succeeded") by OperationName
| extend PassRatePercent = round(100.0 * Passed / Total, 2)

Quantum device operation duration by device (last 24 hours)

Average operation duration in milliseconds per device and operation type over the last 24 hours, based on terminal (Succeeded or Failed) records.

// Average operation duration per device over the last 24 hours.
// Uses terminal records (Succeeded or Failed), which carry the wall-clock DurationMs;
// Started records report a duration of 0 and are excluded.
QuantumProviderAccountDeviceOperationLogs
| where TimeGenerated > ago(24h)
| where ResultType in ("Succeeded", "Failed")
| summarize AvgDurationMs = avg(DurationMs), RunCount = count() by DeviceName, DeviceId, OperationName
| sort by AvgDurationMs desc