Hinweis
Für den Zugriff auf diese Seite ist eine Autorisierung erforderlich. Sie können versuchen, sich anzumelden oder das Verzeichnis zu wechseln.
Für den Zugriff auf diese Seite ist eine Autorisierung erforderlich. Sie können versuchen, das Verzeichnis zu wechseln.
Fügt ein berechnetes Feld oder ein berechnetes Element zu PivotTable hinzu.
Syntax
Ausdruck verwendet werden. AddCalculatedMember (Name, Formel, SolveOrder, Type, DisplayFolder, MeasureGroup, ParentHierarchy, ParentMember, NumberFormat)
Ausdruck Eine Variable, die ein CalculatedMembers-Objekt darstellt.
Parameter
| Name | Erforderlich/Optional | Datentyp | Beschreibung |
|---|---|---|---|
| Name | Erforderlich | String | Der Name des berechneten Elements. |
| Formula | Erforderlich | Variant | Die Formel des berechneten Elements. |
| SolveOrder | Optional | Variant | Die Lösungsreihenfolge für das berechnete Element. |
| Typ | Optional | Variant | Der Typ des berechneten Elements. |
| DisplayFolder | Optional | Variant | Ein Ordner, der zum Anzeigen berechneter Kennzahlen vorhanden ist. |
| MeasureGroup | Optional | Variant | Die Gruppe, zu der das berechnete Element gehört. |
| ParentHierarchy | Optional | Variant | Der übergeordnete Pfad des ParentMember. |
| ParentMember | Optional | Variant | Das übergeordnete Element des berechneten Elements. |
| NumberFormat | Optional | Variant | Das Format von Zahlen, das für berechnete Elemente verwendet wird. |
Rückgabewert
CALCULATEDMEMBER
Hinweise
Das Argument Formel muss über eine gültige MDX-Syntaxanweisung (Multidimensional Expression) verfügen. Das Argument Name muss für den OLAP-Anbieter (Online Analytical Processing) akzeptabel sein.
DisplayFolder
Anzeigeordner sind nur für berechnete Kennzahlen gültig. Sie sind für berechnete Elemente nicht gültig.
Die Zeichenfolge kann Semikolons enthalten . Semikolons kennzeichnen mehrere Anzeigeordner. Wenn Sie z. B. die Zeichenfolgemyfolder1; MyFolder2 wird das berechnete Measure in zwei Anzeigeordnern angezeigt, einer mit dem Namen MyFolder1 und der andere mit dem Namen MyFolder2.
Die Zeichenfolge kann umgekehrte Schrägstriche \aufweisen. Hiermit wird ein hierarchischer Pfad für den Anzeigeordner festgelegt. Wenn Sie z. B. "Stringwelcome\to\seattle" verwenden, gibt es einen Anzeigeordner namens "welcome", der einen Anzeigeordner namens "seattle" enthält. Anzeigeordner sind virtuelle Ordner; Sie existieren nicht wirklich in dem Sinne, wie wir uns Systemordner vorstellen. Sie dienen nur der Anzeige der berechneten Kennzahlen.
NumberFormat
Die Zahlenformate können nur durch Makros festgelegt werden. Es gibt keine Benutzeroberfläche zum Festlegen. Dies ist die einzige Eigenschaft, die nicht über die Benutzeroberfläche festgelegt werden kann. Der Typ ist immer xlNumberFormatTypeDefault , wenn ein berechnetes Element über die Benutzeroberfläche erstellt wird. Die Zahlenformate sind nur für berechnete Elemente gültig. Sie sind nicht gültig für berechnete Maße.
ParentHierarchy
Die übergeordnete Hierarchie kann eine beliebige gültige MDX-Hierarchie sein. Übergeordnete Hierarchien sind nur für berechnete Elemente gültig. Sie sind nicht gültig für berechnete Maße. Wenn ein übergeordnetes Element ausgewählt wird, das sich in einer anderen übergeordneten Hierarchie befindet, wird die übergeordnete Hierarchie automatisch so geändert, dass sie mit der übergeordneten Hierarchie des übergeordneten Elements übereinstimmt. Nehmen wir beispielsweise das folgende Makro für ein berechnetes Element an.
OLEDBConnection.CalculatedMembers.AddCalculatedMember Name:="[UK+US]", _
Formula:= _
"[Customer].[Customer Geography].[Country].&[United Kingdom] + [Customer].[Customer Geography].[Country].&[United States] " _
, Type:=xlCalculatedMember, SolveOrder:=0, ParentHierarchy:= _
"[Account].[Accounts]", ParentMember:= _
"[Customer].[Customer Geography].[Australia]", NumberFormat:= _
xlNumberFormatTypePercent
In diesem Fall haben Sie angegeben, dass das übergeordnete Element aus der [Customer].[Customer Geography] Hierarchie stammt, aber Sie haben die übergeordnete Hierarchie als [Account].[Accounts]angegeben. Wenn das Element erstellt wird, verwendet es die übergeordnete Hierarchie des übergeordneten Mitglieds, die [Customer].[Customer Geography]ist, und wenn Sie im Dialogfeld "Berechnungen verwalten " in der Benutzeroberfläche nachsehen, wird [Customer].[Customer Geography] sie als übergeordnete Hierarchie und nicht als die im Makro angegebene angezeigt, d. h. [Account].[Accounts]. .
Beispiel
Im folgenden Codebeispiel wird einer PivotTable ein berechnetes Measure hinzugefügt.
Hinweis
In beiden Beispielen muss die PivotTable nach dem Erstellen der Berechnung aktualisiert werden, um sie auf der Benutzeroberfläche anzuzeigen.
Sub AddCalculatedMeasure()
Dim pvt As PivotTable
Dim strName As **String**
Dim strFormula As **String**
Dim strDisplayFolder As **String**
Dim strMeasureGroup As **String**
Set pvt = Sheet1.PivotTables("PivotTable1")
strName = "[Measures].[Internet Sales Amount 25 %]"
strFormula = "[Measures].[Internet Sales Amount]*1.25"
strDisplayFolder = "My Folder\Percent Calculations"
strMeasureGroup = "Internet Sales"
pvt.CalculatedMembers. AddCalculatedMember Name:=strName, Formula:=strFormula, Type:=xlCalculatedMeasure, DisplayFolder:=strDisplayFolder, MeasureGroup:=strMeasureGroup, NumberFormat:=xlNumberFormatTypePercent
End Sub
Im folgenden Codebeispiel wird einer PivotTable ein berechnetes Element hinzugefügt.
Sub AddCalculatedMember()
Dim pvt As PivotTable
Dim strName As **String**
Dim strFormula As **String**
Dim strParentHierarchy As **String**
Dim strParentMember As **String**
Set pvt = Sheet1.PivotTables("PivotTable1")
strName = "[Customer].[Customer Geography].[All Customers].[North America]"
strFormula = "[Customer].[Customer Geography].[Country].&[United States] + [Customer].[Customer Geography].[Country].&[Canada]"
strParentHierarchy = "[Customer].[Customer Geography]"
strParentMember = "[Customer].[Customer Geography].[All Customers]"
pvt.CalculatedMembers. AddCalculatedMember Name:=strName, Formula:=strFormula, Type:=xlCalculatedMember, ParentHierarchy:=strParentHierarchy, ParentMember:=strParentMember, SolveOrder:=0, NumberFormat:=xlNumberFormatTypeDefault
End Sub
Support und Feedback
Haben Sie Fragen oder Feedback zu Office VBA oder zu dieser Dokumentation? Unter Office VBA-Support und Feedback finden Sie Hilfestellung zu den Möglichkeiten, wie Sie Support erhalten und Feedback abgeben können.