Deaktivieren der verwalteten SQL Server-Sicherung in Microsoft Azure

Gilt für:SQL Server

In diesem Thema wird beschrieben, wie die verwaltete SQL Server-Sicherung in Microsoft Azure sowohl auf Datenbank- als auch auf Instanzebene deaktiviert oder angehalten wird.

Deaktivieren der verwalteten SQL Server-Sicherung in Microsoft Azure für eine Datenbank

Sie können die Einstellungen für die verwaltete SQL Server-Sicherung in Microsoft Azure deaktivieren, indem Sie die gespeicherte Systemprozedur managed_backup.sp_backup_config_basic (Transact-SQL) verwenden. Der @enable_backup-Parameter wird zum Aktivieren und Deaktivieren von Konfigurationen für die verwaltete SQL Server-Sicherung in Microsoft Azure für eine bestimmte Datenbank verwendet, wobei die Konfigurationseinstellungen mit 1 aktiviert und mit 0 deaktiviert werden.

So deaktivieren Sie die verwalteten SQL Server-Sicherung in Microsoft Azure für eine bestimmte Datenbank:

1. Stellen Sie eine Verbindung mit dem Datenbankmodul her.

2. Klicken Sie in der Standardleiste auf Neue Abfrage.

3. Kopieren Sie das folgende Beispiel, fügen Sie es in das Abfragefenster ein, und klicken Sie auf Ausführen.

EXEC msdb.managed_backup.sp_backup_config_basic  
                @database_name = 'TestDB'   
                ,@enable_backup = 0;  
GO

Deaktivieren der verwalteten SQL Server-Sicherung in Microsoft Azure für alle Datenbanken in der Instanz

Mit dem folgenden Verfahren können Sie Konfigurationseinstellungen für die verwaltete SQL Server-Sicherung in Microsoft Azure für alle Datenbanken deaktivieren, für die die verwaltete SQL Server-Sicherung in Microsoft Azure momentan für die Instanz aktiviert ist. Die Konfigurationseinstellungen wie Speicher-URL, Beibehaltung und SQL-Anmeldeinformationen verbleiben in den Metadaten und können verwendet werden, wenn die verwaltete SQL Server-Sicherung in Microsoft Azure zu einem späteren Zeitpunkt für die Datenbank aktiviert wird. Wenn Sie die Dienste der verwalteten SQL Server-Sicherung in Microsoft Azure vorübergehend anhalten möchten, können Sie den in den folgenden Abschnitten dieses Themas erläuterten Hauptschalter verwenden.

So deaktivieren Sie die verwaltete SQL Server-Sicherung in Microsoft Azure für alle Datenbanken:

1. Stellen Sie eine Verbindung mit dem Datenbankmodul her.

2. Klicken Sie in der Standardleiste auf Neue Abfrage.

3. Kopieren Sie das folgende Beispiel, fügen Sie es in das Abfragefenster ein, und klicken Sie auf Ausführen. Im folgenden Beispiel wird ermittelt, ob die verwaltete SQL Server-Sicherung in Microsoft Azure auf Instanzebene konfiguriert ist, und es werden alle Datenbanken der Instanz identifiziert, für die die verwaltete SQL Server-Sicherung in Microsoft Azure aktiviert ist. Anschließend wird die Systemspeicherprozedur sp_backup_config_basic ausgeführt, um die verwaltete SQL Server-Sicherung in Microsoft Azure zu deaktivieren.

-- Create a working table to store the database names  
Declare @DBNames TABLE  
  
       (  
             RowID int IDENTITY PRIMARY KEY  
             ,DBName varchar(500)  
  
       )  
-- Define the variables  
DECLARE @rowid int  
DECLARE @dbname varchar(500)  
DECLARE @SQL varchar(2000)  
-- Get the database names from the system function  
  
INSERT INTO @DBNames (DBName)  
  
SELECT db_name  
       FROM   
  
       msdb.managed_backup.fn_backup_db_config (NULL)  
       WHERE is_managed_backup_enabled = 1 
       AND is_dropped = 0
  
       --Select DBName from @DBNames  
  
       select @rowid = min(RowID)  
       FROM @DBNames  
  
       WHILE @rowID IS NOT NULL  
       Begin  
  
             Set @dbname = (Select DBName From @DBNames Where RowID = @rowid)  
             Begin  
             Set @SQL = 'EXEC msdb.managed_backup.sp_backup_config_basic    
                @database_name= '''+'' + @dbname+ ''+''',   
                @enable_backup=0'  
  
            EXECUTE (@SQL)  
  
             END  
             Select @rowid = min(RowID)  
             From @DBNames Where RowID > @rowid  
  
       END  

Prüfen Sie die Konfigurationseinstellungen für alle Datenbanken auf der Instanz mit der folgenden Abfrage:

Use msdb;  
GO  
SELECT * FROM managed_backup.fn_backup_db_config (NULL);  
GO  

Standardeinstellungen für die verwaltete SQL Server-Sicherung in Microsoft Azure für die Instanz deaktivieren

Standardeinstellungen auf Instanzebene gelten für alle neuen Datenbanken, die auf dieser Instanz erstellt werden. Wenn Sie die Standardeinstellungen nicht mehr benötigen, können Sie diese Konfiguration mit der gespeicherten Systemprozedur managed_backup.sp_backup_config_basic deaktivieren, indem Sie den Parameter @database_name auf NULL setzen. Durch die Deaktivierung werden die anderen Konfigurationseinstellungen wie Speicher-URL, Beibehaltungseinstellung oder der Name der SQL-Anmeldeinformationen nicht entfernt. Diese Einstellungen werden verwendet, wenn die verwaltete SQL Server-Sicherung in Microsoft Azure zu einem späteren Zeitpunkt für die Instanz aktiviert wird.

So deaktivieren Sie die Standardkonfiguration der verwalteten SQL Server-Sicherung in Microsoft Azure:

1. Stellen Sie eine Verbindung mit dem Datenbankmodul her.

2. Klicken Sie in der Standardleiste auf Neue Abfrage.

3. Kopieren Sie das folgende Beispiel, fügen Sie es in das Abfragefenster ein, und klicken Sie auf Ausführen.

   EXEC msdb.managed_backup.sp_backup_config_basic  
                   @enable_backup = 0;  
   GO
   

Anhalten der verwalteten SQL Server-Sicherung in Microsoft Azure auf Instanzebene

Es kann vorkommen, dass Sie die verwaltete Sicherung von SQL Server für Microsoft Azure-Dienste vorübergehend für kurze Zeit anhalten müssen. Die gespeicherte Systemprozedur managed_backup.sp_backup_master_switch ermöglicht es Ihnen, den SQL Server Managed Backup-Dienst für Microsoft Azure auf Instanzebene zu deaktivieren. Die gleiche gespeicherte Prozedur wird verwendet, um die verwaltete SQL Server-Sicherung in Microsoft Azure fortzusetzen. Mit dem @state-Parameter wird definiert, ob die verwaltete SQL Server-Sicherung in Microsoft Azure aktiviert oder deaktiviert werden soll.

So unterbrechen Sie die verwaltete SQL Server-Sicherung in Microsoft Azure Services mithilfe von Transact-SQL:

1. Stellen Sie eine Verbindung mit dem Datenbankmodul her.

2. Klicken Sie in der Standardleiste auf Neue Abfrage.

3. Kopieren Sie das folgende Beispiel, fügen Sie es in das Abfragefenster ein, und klicken Sie dann auf Ausführen.

Use msdb;  
GO  
EXEC managed_backup.sp_backup_master_switch @new_state=0;  
Go

So setzen Sie die verwaltete SQL Server-Sicherung in Microsoft Azure mit Transact-SQL fort

1. Stellen Sie eine Verbindung mit dem Datenbankmodul her.

2. Klicken Sie in der Standardleiste auf Neue Abfrage.

3. Kopieren Sie das folgende Beispiel, fügen Sie es in das Abfragefenster ein, und klicken Sie dann auf Ausführen.

Use msdb;  
Go  
EXEC managed_backup.sp_backup_master_switch @new_state=1;  
GO  

Verwandte Inhalte

• Aktivieren von SQL Server verwaltetem Backup für Azure