Supervisión de registros en Azure Container Apps con Log Analytics

Azure Container Apps se integra con Azure Monitor Log Analytics para ayudarle a supervisar y analizar los registros de la aplicación contenedora. Al seleccionar esta solución para la supervisión de registros, el entorno de Container Apps incluye un área de trabajo de Log Analytics que proporciona un lugar común para almacenar los datos del registro del sistema y de la aplicación de todas las aplicaciones contenedoras que se ejecutan en el entorno.

Puede acceder a las entradas de registro consultando las tablas de Log Analytics a través del portal de Azure o desde una línea de comandos mediante CLI de Azure.

Azure Container Apps proporciona tres tipos de registro para ayudarle a supervisar y solucionar problemas:

• Registros de consola: la aplicación genera estos registros.
• Registros del sistema: el servicio Container Apps genera estos registros.
• Registros HTTP: la capa de entrada emite estos registros cuando el registro HTTP está habilitado a través de la configuración de diagnóstico.

Registros del sistema

El servicio Container Apps proporciona mensajes de registro del sistema en el nivel de aplicación de contenedor. Los registros del sistema emiten los siguientes mensajes:

Puede acceder a los datos de registro del sistema consultando la ContainerAppSystemLogs_CL tabla. Las columnas específicas de Container Apps más usadas en la tabla son:

Registros de consola

Los registros de consola se originan a partir de los mensajes stderr y stdout de los contenedores de la aplicación de contenedor y los sidecars de Dapr. Puede ver los registros de la consola consultando la tabla ContainerAppConsoleLogs_CL.

Las columnas específicas de Container Apps más utilizadas en ContainerAppConsoleLogs_CL incluyen:

Registros de HTTP

Azure Container Apps puede emitir registros HTTP mediante la configuración de diagnóstico de Azure Monitor en el entorno administrado de Container Apps.

Use registros HTTP para inspeccionar el volumen de solicitudes, las rutas de acceso, los métodos y los resultados de respuesta al diagnosticar el comportamiento de la API y el tráfico web.

El ContainerAppHTTPLogs esquema contiene los siguientes campos y descripciones:

Consulta de registros HTTP en Log Analytics

Use primero las siguientes consultas centradas en la evaluación de prioridades y, a continuación, use los ejemplos de análisis adicionales siguientes.

Visualización de errores HTTP recientes

Utilice esta consulta cuando vea tasas de error elevadas en sus paneles de control, los clientes informen de fallos o quiera hacer un triaje rápido de qué está fallando ahora mismo.

ContainerAppHTTPLogs
| where TimeGenerated > ago(1h)
| where StatusCode >= 400
| project TimeGenerated, ContainerAppName, RevisionName, Method, Path,
  StatusCode, ResponseCodeDetails, RequestDuration, RequestId
| order by TimeGenerated desc
| take 100

Búsqueda de solicitudes lentas

Use esta consulta cuando la aplicación se sienta lenta, está investigando una queja de latencia o desea comprobar una corrección de rendimiento.

ContainerAppHTTPLogs
| where TimeGenerated > ago(1h)
| where ContainerAppName == "<app-name>"
| top 50 by RequestDuration desc
| project TimeGenerated, Method, Path, StatusCode, RequestDuration,
  ReplicaName, UpstreamRequestAttemptCount, RequestId

Seguimiento del volumen de solicitudes y la tasa de errores por revisión

Utilice esta consulta cuando haya implementado una nueva revisión y desee comprobar que funciona correctamente, o cuando esté llevando a cabo una implementación azul/verde y desee comparar dos revisiones en paralelo.

ContainerAppHTTPLogs
| where TimeGenerated > ago(6h)
| where ContainerAppName == "<app-name>"
| summarize Requests = count(),
  Errors = countif(StatusCode >= 500),
  ErrorRatePct = round(100.0 * countif(StatusCode >= 500) / count(), 2),
  P95DurationMs = percentile(RequestDuration, 95)
  by RevisionName, bin(TimeGenerated, 5m)
| order by TimeGenerated desc
| render timechart

Rastrea una única solicitud de principio a fin

Utiliza esta consulta cuando un cliente informe de una transacción fallida concreta y te facilite su identificador de solicitud (el valor del encabezado x-request-id que vio). Debe encontrar esa solicitud exacta y los registros de aplicaciones relacionados.

let _requestId = "<request-id>";
ContainerAppHTTPLogs
| where TimeGenerated > ago(24h)
| where RequestId == _requestId
| project TimeGenerated, ContainerAppName, RevisionName, ReplicaName,
  Method, Path, StatusCode, ResponseCodeDetails, ResponseFlags,
  RequestDuration, UpstreamHost, UserAgent, XForwardedFor

Identifique sus principales endpoints con fallos

Use esta consulta cuando vea muchos errores, pero no sepa dónde centrarse primero. Esta consulta muestra qué rutas de acceso son responsables de la mayoría de los errores, por lo que puede priorizar las correcciones por impacto.

ContainerAppHTTPLogs
| where TimeGenerated > ago(24h)
| where StatusCode >= 400
| summarize Errors = count(),
  DistinctClientIPs = dcount(XForwardedFor),
  SampleStatusCodes = make_set(StatusCode, 5),
  ExampleDetails = take_any(ResponseCodeDetails)
  by ContainerAppName, Method, Path
| order by Errors desc
| take 20

Inspección de registros HTTP recientes

Use esta consulta para inspeccionar los registros de registro HTTP recientes:

ContainerAppHTTPLogs
| where TimeGenerated > ago(2h)
| project TimeGenerated, Method, Path, StatusCode, ContainerAppName, EnvironmentName
| order by TimeGenerated desc
| take 100

Use los ejemplos siguientes para escenarios comunes de análisis de registros HTTP.

Distribución de código de estado

ContainerAppHTTPLogs
| where TimeGenerated > ago(24h)
| summarize Count = count() by toint(StatusCode)
| order by Count desc

Vista centrada en errores (4xx/5xx)

ContainerAppHTTPLogs
| where TimeGenerated > ago(2h)
| extend StatusCodeInt = toint(StatusCode)
| where StatusCodeInt >= 400
| project
    Time=TimeGenerated,
    StatusCode=StatusCodeInt,
    Method,
    Path,
    Details=ResponseCodeDetails,
    EnvName=EnvironmentName,
    AppName=ContainerAppName,
    Revision=RevisionName
| top 100 by Time desc

Latencia (P50/P95/P99) por aplicación y ruta de acceso

ContainerAppHTTPLogs
| where TimeGenerated > ago(2h)
| summarize
    Requests = count(),
    P50 = percentile(RequestDuration, 50),
    P95 = percentile(RequestDuration, 95),
    P99 = percentile(RequestDuration, 99)
  by ContainerAppName, Path
| order by P95 desc

Consultar registros usando Log Analytics

Log Analytics es una herramienta de Azure Portal que puede usar para ver y analizar los datos de registro. Mediante el uso de Log Analytics, puede escribir consultas de Kusto y, a continuación, ordenar, filtrar y visualizar los resultados en gráficos para detectar tendencias e identificar problemas. Puede trabajar de forma interactiva con los resultados de la consulta o utilizarlos con otras características, como las alertas, los paneles y los libros.

Portal de Azure

Abra Log Analytics desde Registros en el menú de la barra lateral de la página de la aplicación contenedora. También puede iniciar Log Analytics desde Monitor > Logs.

Consulte los registros mediante las tablas enumeradas en la categoría Registros personalizados de la pestaña Tablas . Las tablas de esta categoría son ContainerAppSystemLogs_CL y ContainerAppConsoleLogs_CL.

La siguiente consulta de Kusto muestra entradas de registro de consola para la aplicación contenedora denominada album-api.

ContainerAppConsoleLogs_CL
| where ContainerAppName_s == 'album-api'
| project Time=TimeGenerated, AppName=ContainerAppName_s, Revision=RevisionName_s, Container=ContainerName_s, Message=Log_s
| take 100

La siguiente consulta de Kusto muestra entradas de registro del sistema para la aplicación contenedora denominada album-api.

ContainerAppSystemLogs_CL
| where ContainerAppName_s == 'album-api'
| project Time=TimeGenerated, EnvName=EnvironmentName_s, AppName=ContainerAppName_s, Revision=RevisionName_s, Message=Log_s
| take 100

Para obtener más información sobre las consultas de registro y Log Analytics, consulte el tutorial Log Analytics.

CLI de Azure o PowerShell

Puede consultar los registros de Container Apps mediante CLI de Azure.

En este ejemplo, las consultas de la CLI de Azure generan una tabla que contiene entradas de registros para el nombre de la aplicación de contenedor album-api. Los parámetros después del project operador especifican las columnas de tabla. La variable $WORKSPACE_CUSTOMER_ID tiene el GUID del área de trabajo de Log Analytics.

En este ejemplo se consulta la tabla ContainerAppConsoleLogs_CL:

az monitor log-analytics query --workspace $WORKSPACE_CUSTOMER_ID --analytics-query "ContainerAppConsoleLogs_CL | where ContainerAppName_s == 'album-api' | project Time=TimeGenerated, AppName=ContainerAppName_s, Revision=RevisionName_s, Container=ContainerName_s, Message=Log_s, LogLevel_s | take 5" --out table

$queryResults = Invoke-AzOperationalInsightsQuery -WorkspaceId $WORKSPACE_CUSTOMER_ID -Query "ContainerAppConsoleLogs_CL | where ContainerAppName_s == 'album-api' | project Time=TimeGenerated, AppName=ContainerAppName_s, Revision=RevisionName_s, Container=ContainerName_s, Message=Log_s, LogLevel_s | take 5"
$queryResults.Results

En este ejemplo se consulta la tabla ContainerAppSystemLogs_CL:

az monitor log-analytics query --workspace $WORKSPACE_CUSTOMER_ID --analytics-query "ContainerAppSystemLogs_CL | where ContainerAppName_s == 'album-api' | project Time=TimeGenerated, AppName=ContainerAppName_s, Revision=RevisionName_s, Message=Log_s, LogLevel_s | take 5" --out table

$queryResults = Invoke-AzOperationalInsightsQuery -WorkspaceId $WORKSPACE_CUSTOMER_ID -Query "ContainerAppSystemLogs_CL | where ContainerAppName_s == 'album-api' | project Time=TimeGenerated, AppName=ContainerAppName_s, Revision=RevisionName_s, Message=Log_s, LogLevel_s | take 5"
$queryResults.Results

Pasos siguientes