Configurare il connettore per OPC UA

1. Selezionare i dispositivi e quindi Crea dispositivo:

   

   Suggerimento

   Usare la casella di filtro per cercare i dispositivi.

2. Nella pagina Basics, inserire il nome del dispositivo e selezionare Nuovo nel riquadro Microsoft.OpcUa per aggiungere un endpoint per il dispositivo.

   

3. Immettere le informazioni dell'endpoint. Ad esempio, per usare il simulatore OPC PLC, immettere i valori seguenti:

   Campo	Valore
   Nome	opc-ua-connector-0
   Connettore per l'URL per OPC UA	opc.tcp://opcplc-000000:50000
   Autenticazione utente	Anonymous

4. Seleziona Avanti. Nella pagina Informazioni aggiuntive immettere le proprietà personalizzate per il dispositivo.

5. Selezionare Avanti per esaminare i dettagli del dispositivo. Successivamente, seleziona Crea.

Eseguire i comandi seguenti:

az iot ops ns device create \
  -n opc-ua-connector-cli \
  -g {your resource group name} \
  --instance {your instance name}

az iot ops ns device endpoint inbound add opcua \
  --device opc-ua-connector-cli \
  -g {your resource group name} \
  -i {your instance name} \
  --name opc-ua-connector-0 \
  --endpoint-address "opc.tcp://opcplc-000000:50000"

Per altre informazioni, vedere az iot ops ns device.

Distribuire il seguente modello Bicep per creare un dispositivo con un endpoint in ingresso per il connettore OPC UA. Sostituire i segnaposto <AIO_NAMESPACE_NAME> e <CUSTOM_LOCATION_NAME> rispettivamente con il nome dello spazio dei nomi Operazioni di Azure IoT e il nome della posizione personalizzata.

param deviceRegistryNamespaceName string = '<AIO_NAMESPACE_NAME>'
param customLocationName string = '<CUSTOM_LOCATION_NAME>'

resource deviceRegistryNamespace 'Microsoft.DeviceRegistry/namespaces@2026-04-01' existing = {
  name: deviceRegistryNamespaceName
}

resource customLocation 'Microsoft.ExtendedLocation/customLocations@2021-08-31-preview' existing = {
  name: customLocationName
}

resource device 'Microsoft.DeviceRegistry/namespaces/devices@2026-04-01' = {
  name: 'opc-ua-connector-bicep'
  parent: deviceRegistryNamespace
  location: resourceGroup().location
  extendedLocation: {
    type: 'CustomLocation'
    name: customLocation.id
  }
  properties: {
    endpoints: {
      outbound: {
        assigned: {}
      }
      inbound: {
        'opc-ua-connector-0': {
          endpointType: 'Microsoft.OpcUa'
          address: 'opc.tcp://opcplc-000000:50000'
          authentication: {
            method: 'Anonymous'
          }
        }
      }
    }
  }
}

Nell'esperienza operativa, quando si aggiunge l'endpoint in ingresso e si sceglie la modalità di autenticazione password nome utente , selezionare Aggiungi riferimento per aggiungere i riferimenti al segreto per il nome utente e la password. L'esperienza operativa offre due opzioni:

• Creare un nuovo segreto: carica il valore in Azure Key Vault e lo sincronizza con il cluster come segreto sincronizzato.
• Aggiungi da Azure Key Vault: sincronizza un segreto esistente di Key Vault con il cluster.

L'esperienza operativa salva sia i riferimenti al nome utente che alla password in una singola risorsa privata sincronizzata nel cluster e si assegna un nome al segreto sincronizzato.

Per altre informazioni, vedere Aggiungere e usare segreti.

1. Assicurarsi che il nome utente e la password siano archiviati come segreti in Azure Key Vault. Per altre informazioni, vedere Aggiungi segreti a Azure Key Vault.

2. Creare un singolo segreto sincronizzato nel cluster che fa riferimento a entrambi i segreti Key Vault. Nell'esempio seguente viene creato un segreto sincronizzato denominato my-endpoint-creds che esegue il mapping dei segreti Key Vault my-kv-username e my-kv-password alle chiavi username e password:

   az iot ops secretsync secret set \
     --instance <your-instance-name> \
     --resource-group <your-resource-group> \
     --name my-endpoint-creds \
     --secret target=username source=my-kv-username \
     --secret target=password source=my-kv-password
   

   Per ulteriori informazioni, consultare az iot ops secretsync secret set.

3. Usare il comando az iot ops ns device endpoint inbound add con i parametri --user-ref e --pass-ref per fare riferimento al nome e alla chiave del segreto sincronizzato rispettivamente per il nome utente e la password, ad esempio my-endpoint-creds/username e my-endpoint-creds/password.

1. Assicurarsi che il nome utente e la password siano archiviati come segreti in Azure Key Vault e che un segreto sincronizzato nel cluster faccia riferimento a entrambi i segreti Key Vault. È possibile creare il segreto sincronizzato tramite l'esperienza operativa o usando il interfaccia della riga di comando di Azure. Per altre informazioni, vedere Gestire i segreti per la distribuzione Operazioni di Azure IoT.

2. Modificare il blocco authentication della configurazione Bicep affinché il connettore faccia riferimento al segreto sincronizzato nel cluster. I usernameSecretName valori e passwordSecretName usano il formato <synced-secret-name>/<key>:

   authentication: {
       method: 'UsernamePassword'
           usernamePasswordCredentials: {
               usernameSecretName: 'my-endpoint-creds/username'
               passwordSecretName: 'my-endpoint-creds/password'
           }
   }
   

Nell'esperienza operativa, quando si aggiunge l'endpoint in ingresso e si sceglie la modalità di autenticazione del certificato X509 , selezionare Aggiungi riferimento per aggiungere il riferimento al segreto per il certificato client e la chiave privata. L'esperienza operativa offre due opzioni:

• Creare un nuovo segreto: carica i file di certificato e di chiave privata in Azure Key Vault e li sincronizza con il cluster come segreto sincronizzato.
• Aggiungi da Azure Key Vault: sincronizza i segreti di Key Vault esistenti nel cluster.

L'esperienza operativa salva i riferimenti al certificato e alla chiave in una singola risorsa privata sincronizzata nel cluster e si assegna un nome al segreto sincronizzato.

Per altre informazioni, vedere Sincronizzare un certificato client e una chiave privata per TLS reciproco.

1. Assicurarsi che il certificato client e la chiave privata siano archiviati come segreti in Azure Key Vault. Per altre informazioni, vedere Sincronizzare un certificato client e una chiave privata per TLS reciproco.

2. Creare un singolo segreto sincronizzato nel cluster che fa riferimento a entrambi i segreti Key Vault. Nell'esempio seguente viene creato un segreto sincronizzato denominato my-endpoint-cert che esegue il mapping dei segreti Key Vault my-kv-client-cert e my-kv-client-key alle chiavi certificate e privateKey:

   az iot ops secretsync secret set \
     --instance <your-instance-name> \
     --resource-group <your-resource-group> \
     --name my-endpoint-cert \
     --secret target=certificate source=my-kv-client-cert \
     --secret target=privateKey source=my-kv-client-key
   

   Per ulteriori informazioni, consultare az iot ops secretsync secret set.

3. Usare il comando az iot ops ns device endpoint inbound add con i --cert-ref parametri e --key-ref per fare riferimento al nome e alla chiave privata sincronizzati per il certificato e la chiave privata, ad esempio my-endpoint-cert/certificate e my-endpoint-cert/privateKey. Per includere i certificati intermedi, aggiungere --icr my-endpoint-cert/intermediateCerts.

1. Assicurarsi che il certificato client e la chiave privata siano archiviati come segreti in Azure Key Vault e che un segreto sincronizzato nel cluster faccia riferimento a entrambi i segreti Key Vault. È possibile creare il segreto sincronizzato tramite l'esperienza operativa o usando il interfaccia della riga di comando di Azure. Per altre informazioni, vedere Sincronizzare un certificato client e una chiave privata per TLS reciproco.

2. Modifica il blocco authentication della configurazione di Bicep per l'endpoint in entrata del dispositivo in modo che faccia riferimento al segreto sincronizzato sul cluster. I certificateSecretName valori e keySecretName usano il formato <synced-secret-name>/<key>:

   authentication: {
       method: 'Certificate'
           x509Credentials: {
               certificateSecretName: 'my-endpoint-cert/certificate'
               keySecretName: 'my-endpoint-cert/privateKey'
           }
   }
   

Per aggiungere un asset nell'esperienza operativa, seguire questa procedura:

1. Selezionare la scheda Asset. Prima di creare gli asset, viene visualizzata la schermata seguente:

   

   Suggerimento

   Usare la casella di filtro per cercare gli asset.

2. Seleziona Crea asset.

3. Nella schermata dei dettagli dell'asset, immettere le informazioni sull'asset seguenti:

   • Endpoint in ingresso. Selezionare l'endpoint in ingresso del dispositivo dall'elenco.
   • Nome dell'asset
   • Descrizione

4. Configurare il set di proprietà personalizzate da associare all'asset. È possibile accettare l'elenco predefinito di proprietà o aggiungerne uno personalizzato. Per impostazione predefinita, sono disponibili le proprietà seguenti:

   • Fabbricante
   • URI produttore
   • Modello
   • Codice prodotto
   • Versione hardware
   • Versione software
   • Numero di serie
   • URI della documentazione

   

5. Selezionare Avanti per passare alla pagina Set di dati .

Aggiungere un set di dati a un asset

Un set di dati definisce dove il connettore invia i dati raccolti da una raccolta di punti dati. Un asset OPC UA può avere più set di dati. Per creare un set di dati:

1. Selezionare Crea set di dati.

2. Immettere i dettagli per il set di dati, ad esempio il nome e la destinazione. Per gli asset OPC UA, la destinazione è un argomento MQTT. Per esempio:

   

   Usare il campo Istanza iniziale per specificare il nodo iniziale per la risoluzione dei percorsi di esplorazione relativi per i punti dati nel set di dati. Per maggiori informazioni, consulta Resolve nodi dinamici utilizzando i percorsi di navigazione.

3. Selezionare Crea e quindi creare il set di dati.

Aggiungere singoli punti dati a un set di dati

È ora possibile definire i punti dati associati al set di dati. Per aggiungere punti dati OPC UA:

1. Selezionare Aggiungi punto dati.

2. Immettere i dettagli del punto dati:

   • Origine dati. Questo valore è l'ID nodo del server OPC UA.
   • Nome punto dati (facoltativo). Questo valore è il nome descrittivo che si vuole usare per il punto dati. Se non si specifica un nome di punto dati, l'ID nodo viene usato come nome del punto dati.
   • Intervallo di campionamento (millisecondi). È possibile eseguire l'override del valore predefinito per questo punto dati.
   • Dimensioni della coda. È possibile eseguire l'override del valore predefinito per questo punto dati.
   • Numero di frame chiave. Per impostazione predefinita, i frame chiave sono disattivati. Usare questa impostazione per abilitare i fotogrammi chiave e specificare la frequenza con cui il connettore genera fotogrammi chiave. Per ulteriori informazioni, vedi Configura i keyframe per il recupero dello stato.

   

   La tabella seguente mostra alcuni valori di punti dati di esempio che è possibile usare con il simulatore OPC PLC predefinito:

   L'origine dei dati	Nome punto dati
   ns=3;s=FastUInt10	Temperatura
   ns=3;s=FastUInt100	Umidità

   Annotazioni

   Se si usano percorsi di esplorazione relativi per risolvere i nodi dinamici, il campo Origine dati contiene un percorso di esplorazione relativo. Per maggiori informazioni, consulta Resolve nodi dinamici utilizzando i percorsi di navigazione.

3. Nella pagina Punti dati selezionare Avanti per passare alla pagina Aggiungi eventi .

Usare i comandi seguenti per aggiungere un asset termostato al dispositivo usando il interfaccia della riga di comando di Azure. I comandi aggiungono un set di dati e due punti dati all'asset usando il datapoint add comando :

# Create the asset
az iot ops ns asset opcua create \
  --name thermostat \
  --instance {your instance name} \
  -g {your resource group name} \
  --device opc-ua-connector-cli \
  --endpoint opc-ua-connector-0 \
  --description 'A simulated thermostat asset'

# Add the dataset
az iot ops ns asset opcua dataset add \
  --asset thermostat \
  --instance {your instance name} \
  -g {your resource group name} \
  --name oven \
  --data-source "" \
  --dest topic="azure-iot-operations/data/thermostat" retain=Never qos=Qos1 ttl=3600

# Add the data points
az iot ops ns asset opcua datapoint add \
  --asset thermostat \
  --instance {your instance name} \
  -g {your resource group name} \
  --dataset oven \
  --name temperature \
  --data-source "ns=3;s=FastUInt10"

az iot ops ns asset opcua datapoint add \
  --asset thermostat \
  --instance {your instance name} \
  -g {your resource group name} \
  --dataset oven \
  --name humidity \
  --data-source "ns=3;s=FastUInt100"

# Show the dataset and datapoints
az iot ops ns asset opcua dataset show \
  --asset thermostat \
  -n oven \
  -g {your resource group name} \
  --instance {your instance name}

Quando si crea un asset usando il interfaccia della riga di comando di Azure, è possibile definire:

• Più punti dati usando il comando datapoint add più volte.
• Gruppi di eventi multipli ed eventi usando i event-group add comandi e event add .
• Informazioni facoltative per l'asset, ad esempio:
  • Fabbricante
  • URI produttore
  • Modello
  • Codice prodotto
  • Versione hardware
  • Versione software
  • Numero di serie
  • URI della documentazione
• Valori del set di dati per l'intervallo di campionamento, l'intervallo di pubblicazione, il numero di frame chiave e le dimensioni della coda.
• Valori specifici del punto dati per intervallo di campionamento, intervallo di pubblicazione e dimensioni della coda.
• Valori specifici per evento per intervallo di campionamento e dimensione della coda.
• Modalità osservabilità per ogni punto dati ed evento

Distribuire il modello Bicep seguente per creare un asset che pubblica messaggi dal dispositivo illustrato in precedenza in un topic MQTT. Sostituire i segnaposto <AIO_NAMESPACE_NAME> e <CUSTOM_LOCATION_NAME> rispettivamente con il nome dello spazio dei nomi Operazioni di Azure IoT e il nome della posizione personalizzata.

param deviceRegistryNamespaceName string = '<AIO_NAMESPACE_NAME>'
param customLocationName string = '<CUSTOM_LOCATION_NAME>'

resource deviceRegistryNamespace 'Microsoft.DeviceRegistry/namespaces@2026-04-01' existing = {
  name: deviceRegistryNamespaceName
}

resource customLocation 'Microsoft.ExtendedLocation/customLocations@2021-08-31-preview' existing = {
  name: customLocationName
}

resource asset 'Microsoft.DeviceRegistry/namespaces/assets@2026-04-01' = {
  name: 'thermostat'
  parent: deviceRegistryNamespace
  location: resourceGroup().location
  extendedLocation: {
    type: 'CustomLocation'
    name: customLocation.id
  }
  properties: {
    displayName: 'thermostat'
    description: 'A simulated thermostat asset'
    enabled: true

    deviceRef: {
      deviceName: 'opc-ua-connector-bicep'
      endpointName: 'opc-ua-connector-0'
    }

    defaultDatasetsConfiguration: '{}'
    defaultEventsConfiguration: '{}'

    datasets: [
      {
        name: 'oven'
        datasetConfiguration: '{}'
        dataPoints: [
          {
            name: 'temperature'
            dataSource: 'ns=3;s=FastUInt10'
            dataPointConfiguration: '{}'
          }
          {
            name: 'humidity'
            dataSource: 'ns=3;s=FastUInt100'
            dataPointConfiguration: '{}'
          }
        ]
        destinations: [
          {
            target: 'Mqtt'
            configuration: {
              topic: 'azure-iot-operations/data/thermostat'
              qos: 'Qos1'
              retain: 'Never'
              ttl: 3600
            }
          }
        ]
      }
    ]
  }
}

1. Nell'esperienza operativa, seleziona Risorse e poi apri o crea l'asset my-triggered-asset . Seleziona l'endpoint opc-ua-connector-0 in entrata sul dispositivo con namespaced che hai creato in precedenza.

2. Nella pagina Dataset , seleziona o crea il telemetry dataset. Imposta l'argomento di destinazione a azure-iot-operations/data/my-triggered-asset, l'intervallo di pubblicazione a 1000 millisecondi e l'intervallo di campionamento a 500 millisecondi.

3. Aggiungi i seguenti punti dati al dataset. I nomi dei punti dati sono distinti dalla maiuscola minuscola.

   Nome punto dati	L'origine dei dati
   dataPoint-SlowUInt1	nsu=http://microsoft.com/Opc/OpcPlc/;s=SlowUInt1
   dataPoint-FastUInt1	nsu=http://microsoft.com/Opc/OpcPlc/;s=FastUInt1
   dataPoint-FastUInt2	nsu=http://microsoft.com/Opc/OpcPlc/;s=FastUInt2

4. Nelle impostazioni del dataset, imposta Triggering item su dataPoint-SlowUInt1 e Triggering la modalità di segnalazione degli item su Sampling.

   

5. Salva la configurazione dell'asset.

La interfaccia della riga di comando di Azure attualmente non supporta le impostazioni triggeringItem o triggeringItemReportingMode. Usa l'esperienza operativa o Bicep per configurare il triggering del dataset. Non usare un comando generico di aggiornamento asset per modificare queste proprietà specifiche del dataset del connettore.

Distribuisci il seguente modello Bicep per creare un asset namespaced con l'attivazione del dataset. Sostituisci <IOT_OPERATIONS_NAMESPACE_NAME> e <CUSTOM_LOCATION_NAME> con il tuo namespace Operazioni di Azure IoT e i nomi personalizzati delle località:

param iotOperationsNamespaceName string = '<IOT_OPERATIONS_NAMESPACE_NAME>'
param customLocationName string = '<CUSTOM_LOCATION_NAME>'

resource iotOperationsNamespace 'Microsoft.DeviceRegistry/namespaces@2026-04-01' existing = {
  name: iotOperationsNamespaceName
}

resource customLocation 'Microsoft.ExtendedLocation/customLocations@2021-08-31-preview' existing = {
  name: customLocationName
}

resource asset 'Microsoft.DeviceRegistry/namespaces/assets@2026-04-01' = {
  name: 'my-triggered-asset'
  parent: iotOperationsNamespace
  location: resourceGroup().location
  extendedLocation: {
    type: 'CustomLocation'
    name: customLocation.id
  }
  properties: {
    displayName: 'my-triggered-asset'
    enabled: true
    deviceRef: {
      deviceName: 'opc-ua-connector-bicep'
      endpointName: 'opc-ua-connector-0'
    }
    defaultDatasetsConfiguration: '{}'
    defaultEventsConfiguration: '{}'
    datasets: [
      {
        name: 'telemetry'
        datasetConfiguration: '{"publishingInterval":1000,"samplingInterval":500,"triggeringItem":"dataPoint-SlowUInt1","triggeringItemReportingMode":"Sampling"}'
        dataPoints: [
          {
            name: 'dataPoint-SlowUInt1'
            dataSource: 'nsu=http://microsoft.com/Opc/OpcPlc/;s=SlowUInt1'
            dataPointConfiguration: '{}'
          }
          {
            name: 'dataPoint-FastUInt1'
            dataSource: 'nsu=http://microsoft.com/Opc/OpcPlc/;s=FastUInt1'
            dataPointConfiguration: '{}'
          }
          {
            name: 'dataPoint-FastUInt2'
            dataSource: 'nsu=http://microsoft.com/Opc/OpcPlc/;s=FastUInt2'
            dataPointConfiguration: '{}'
          }
        ]
        destinations: [
          {
            target: 'Mqtt'
            configuration: {
              topic: 'azure-iot-operations/data/my-triggered-asset'
              qos: 'Qos1'
              retain: 'Never'
              ttl: 3600
            }
          }
        ]
      }
    ]
  }
}

Aggiungere un gruppo di eventi a un asset

Un gruppo di eventi definisce la posizione in cui il connettore invia i dati ricevuti da una raccolta di eventi. Un asset OPC UA può avere più gruppi di eventi. Per creare un gruppo di eventi:

1. Selezionare Crea gruppo di eventi.

2. Immettere un nome per il gruppo di eventi ed eventuali altri dettagli obbligatori:

   

3. Selezionare Crea e avanti per creare il gruppo di eventi e passare alla pagina Elenco di eventi per gli avvisi.

Aggiungere eventi a un gruppo di eventi

È ora possibile definire gli eventi associati al gruppo di eventi. Per aggiungere eventi OPC UA:

1. Selezionare Aggiungi evento.

2. Immettere i dettagli dell'evento:

   • Origine dati. Questo valore è il componente di notifica dell'evento del server OPC UA.
   • Nome dell'evento (facoltativo). Questo valore è il nome descrittivo che si vuole usare per l'evento. Se non si specifica un nome dell'evento, il componente di notifica dell'evento viene usato come nome dell'evento.
   • Argomento. Argomento MQTT in cui si desidera pubblicare l'evento.
   • Intervallo di campionamento (millisecondi). Puoi sovrascrivere il valore predefinito di questo evento.
   • Dimensioni della coda. Puoi sovrascrivere il valore predefinito di questo evento.
   • Avviare l'istanza. Questo valore è il nodo iniziale per la risoluzione dei percorsi di esplorazione relativi per questo evento. Questo campo è obbligatorio se si usano percorsi di esplorazione relativi nel campo Origine dati. Per maggiori informazioni, consulta Resolve nodi dinamici utilizzando i percorsi di navigazione.
   • Filtro eventi. Una configurazione opzionale che seleziona e rinomina i campi nella notifica dell'evento. Per maggiori informazioni, consulta i campi Seleziona e rinomina l'evento.

   

3. Selezionare Gestisci impostazioni predefinite per configurare le impostazioni dell'evento predefinite per l'asset. Queste impostazioni si applicano agli eventi OPC UA appartenenti all'asset. È possibile eseguire l'override di queste impostazioni per ogni evento aggiunto. Le impostazioni dell'evento predefinite includono:

   • Intervallo di pubblicazione (millisecondi): la velocità con cui il server OPC UA deve pubblicare i dati.
   • Dimensioni coda: la profondità della coda per contenere i dati di campionamento prima di pubblicarli.

Per aggiungere un gruppo di eventi ed eventi a un asset esistente, usare i az iot ops ns asset opcua event-group comandi e az iot ops ns asset opcua event :

# Add an event group to the thermostat asset
az iot ops ns asset opcua event-group add \
  --data-source "" \
  --asset thermostat \
  --instance {your instance name} \
  -g {your resource group name} \
  --name alerts \
  --dest topic="azure-iot-operations/events/test-thermostat-cli" retain=Never qos=Qos1 ttl=3600

# Add an event to the event group
az iot ops ns asset opcua event add \
  --asset thermostat \
  --instance {your instance name} \
  -g {your resource group name} \
  --event-group alerts \
  --name serverObjectNotifier \
  --data-source "ns=0;i=2253"

# List the event groups for the asset
az iot ops ns asset opcua event-group list \
  --asset thermostat \
  --instance {your instance name} \
  -g {your resource group name}

Quando si aggiunge un gruppo di eventi usando il interfaccia della riga di comando di Azure, è possibile configurare:

• Nome del gruppo di eventi e origine dati
• Intervallo di pubblicazione e dimensioni della coda
• Destinazioni evento (argomento MQTT, QoS, retain, TTL)

Per aggiungere singoli eventi a un gruppo di eventi, usare il az iot ops ns asset opcua event add comando con il --event-group parametro .

Per rimuovere un gruppo di eventi, usare il az iot ops ns asset opcua event-group remove comando .

Per aggiungere eventi e gruppi di eventi a un asset usando Bicep, includere la matrice eventGroups nelle proprietà dell'asset. Ogni gruppo di eventi può contenere una events matrice con singoli eventi:

eventGroups: [
  {
    name: 'alerts'
    eventGroupConfiguration: '{"publishingInterval":1000,"queueSize":10}'
    events: [
      {
        name: 'serverObjectNotifier'
        dataSource: 'ns=0;i=2253'
        eventConfiguration: '{}'
        destinations: [
          {
            target: 'Mqtt'
            configuration: {
              topic: 'azure-iot-operations/events/test-thermostat-bicep'
              qos: 'Qos1'
              retain: 'Never'
              ttl: 3600
            }
          }
        ]
      }
    ]
  }
]

La eventGroupConfiguration proprietà è un oggetto JSON stringato che può includere impostazioni specifiche del connettore, publishingInterval ad esempio e queueSize. I singoli eventi usano la eventConfiguration proprietà per le impostazioni specifiche dell'evento, tra cui per evento destinations.

Esamina il tuo asset e i dettagli relativi ai punti dati e agli eventi OPC UA. Apportare eventuali modifiche necessarie:

Per esaminare la configurazione dell'asset, usare i comandi seguenti:

# View the complete asset details
az iot ops ns asset show \
  --name thermostat \
  --instance {your instance name} \
  -g {your resource group name}

# List datasets and data points
az iot ops ns asset opcua dataset list \
  --asset thermostat \
  --instance {your instance name} \
  -g {your resource group name}

# List event groups
az iot ops ns asset opcua event-group list \
  --asset thermostat \
  --instance {your instance name} \
  -g {your resource group name}

Per esaminare il template Bicep prima della distribuzione, utilizzare l'operazione what-if:

az deployment group what-if --resource-group {your resource group name} --template-file asset.bicep

Questo comando mostra le modifiche apportate alle risorse Azure senza distribuirle.

Individuare e selezionare l'asset creato in precedenza. Usare le schede Dettagli asset, punti dati ed Eventi per apportare eventuali modifiche:

Nella scheda Visualizza punti dati per un set di dati è possibile aggiungere punti dati, aggiornare i punti dati esistenti o rimuovere i punti dati.

Per aggiornare un punto dati, selezionare un punto dati esistente e aggiornare le informazioni sul punto dati. Selezionare quindi Aggiorna:

Per rimuovere i punti dati, selezionare uno o più punti dati e quindi selezionare Rimuovi punti dati:

È anche possibile aggiungere, aggiornare ed eliminare eventi e proprietà nello stesso modo.

Dopo aver apportato tutte le modifiche, selezionare Salva per salvare le modifiche.

Per elencare gli asset associati a un endpoint specifico, usare il comando seguente:

az iot ops ns asset query \
  --device {your device name} \
  --endpoint {your endpoint name} \
  -g {your resource group name} \
  --instance {your instance name}

Per visualizzare i dettagli dell'asset "termostato", usare il comando seguente:

az iot ops ns asset show \
  --name thermostat \
  --instance {your instance name} \
  -g {your resource group}

Per aggiornare un asset, usare il comando az iot ops ns asset opcua update. Ad esempio, per aggiornare la descrizione dell'asset, usare un comando simile all'esempio seguente:

az iot ops ns asset opcua update \
  --name thermostat \
  --instance {your instance name} \
  -g {your resource group} \
  --description "Updated factory PLC"

Per elencare i punti dati dell'asset termostato in un set di dati, usare il comando seguente:

az iot ops ns asset opcua dataset show \
  --asset thermostat \
  --name oven \
  -g {your resource group} \
  --instance {your instance name}

Per elencare i gruppi di eventi dell'asset termostato, usare il comando seguente:

az iot ops ns asset opcua event-group list \
  --asset thermostat \
  -g {your resource group} \
  --instance {your instance name}

Per aggiungere un nuovo punto dati all'asset termostato, usare un comando simile all'esempio seguente:

az iot ops ns asset opcua datapoint add \
  --asset thermostat \
  --instance {your instance name} \
  -g {your resource group name} \
  --dataset oven \
  --name humidity \
  --data-source "ns=3;s=FastUInt100"

Per eliminare un punto dati, usare il az iot ops ns asset opcua datapoint remove comando .

È possibile gestire i gruppi di eventi di un asset usando i az iot ops ns asset opcua event-group comandi .

Per recuperare un asset usando Bicep, usare un modello simile all'esempio seguente:

param deviceRegistryNamespaceName string = '<AIO_NAMESPACE_NAME>'

resource deviceRegistryNamespace 'Microsoft.DeviceRegistry/namespaces@2026-04-01' existing = {
  name: deviceRegistryNamespaceName
}

resource asset 'Microsoft.DeviceRegistry/namespaces/assets@2026-04-01' existing = {
  name: 'thermostat'
  parent: deviceRegistryNamespace
}

output asset object = asset

Per aggiornare un asset esistente, ad esempio per modificare la descrizione e aggiungere un punto dati, usare un modello come nell'esempio seguente:

param deviceRegistryNamespaceName string = '<AIO_NAMESPACE_NAME>'
param customLocationName string = '<CUSTOM_LOCATION_NAME>'

resource deviceRegistryNamespace 'Microsoft.DeviceRegistry/namespaces@2026-04-01' existing = {
  name: deviceRegistryNamespaceName
}

resource customLocation 'Microsoft.ExtendedLocation/customLocations@2021-08-31-preview' existing = {
  name: customLocationName
}

resource asset 'Microsoft.DeviceRegistry/namespaces/assets@2026-04-01' = {
  name: 'thermostat'
  parent: deviceRegistryNamespace
  location: resourceGroup().location
  extendedLocation: {
    type: 'CustomLocation'
    name: customLocation.id
  }
  properties: {
    displayName: 'thermostat'
    description: 'Updated thermostat asset with voltage data point'
    enabled: true

    deviceRef: {
      deviceName: 'opc-ua-connector-bicep'
      endpointName: 'opc-ua-connector-0'
    }

    defaultDatasetsConfiguration: '{}'
    defaultEventsConfiguration: '{}'

    datasets: [
      {
        name: 'oven'
        datasetConfiguration: '{}'
        dataPoints: [
          {
            name: 'temperature'
            dataSource: 'ns=3;s=FastUInt10'
            dataPointConfiguration: '{}'
          }
          {
            name: 'humidity'
            dataSource: 'ns=3;s=FastUInt100'
            dataPointConfiguration: '{}'
          }
          {
            name: 'voltage'
            dataSource: 'ns=3;s=FastUInt101'
            dataPointConfiguration: '{}'
          }
        ]
        destinations: [
          {
            target: 'Mqtt'
            configuration: {
              topic: 'azure-iot-operations/data/thermostat'
              qos: 'Qos1'
              retain: 'Never'
              ttl: 3600
            }
          }
        ]
      }
    ]
  }
}

Per eliminare un asset, selezionare l'asset da eliminare. Nella pagina dei dettagli dell'Asset, selezionare Elimina. Confermare le modifiche per eliminare l'asset:

Per eliminare un asset, usare un comando simile all'esempio seguente:

az iot ops ns asset delete \
  --name thermostat \
  -g {your resource group name} \
  --instance {your instance name}

Per eliminare singole risorse usando Bicep, vedere Stack di distribuzione.