Monitorare i log di App contenitore di Azure con Log Analytics

App contenitore di Azure si integra con Monitoraggio di Azure Log Analytics per monitorare e analizzare i log dell'app contenitore. Quando si seleziona questa soluzione per il monitoraggio dei log, l'ambiente App contenitore include un'area di lavoro Log Analytics che fornisce una posizione comune per archiviare i dati di sistema e di log applicazioni da tutte le app contenitore in esecuzione nell'ambiente.

È possibile accedere alle voci del log eseguendo query nelle tabelle di Log Analytics tramite il portale di Azure o una shell di comando usando interfaccia della riga di comando di Azure.

App contenitore di Azure offre tre tipi di log che consentono di monitorare e risolvere i problemi:

• Log della console: l'applicazione genera questi log.
• Log di sistema: il servizio App contenitore genera questi log.
• Log HTTP: il livello di ingresso genera questi log quando la registrazione HTTP è abilitata tramite le impostazioni di diagnostica.

Log di sistema

Il servizio App contenitore fornisce messaggi di log di sistema a livello di app contenitore. I log di sistema generano i messaggi seguenti:

È possibile accedere ai dati del log di sistema eseguendo una query sulla ContainerAppSystemLogs_CL tabella. Le colonne specifiche di App contenitore più comunemente usate nella tabella sono:

Log della console

I log della console provengono dai messaggi stderr e stdout dai contenitori nell'app contenitore e dai sidecar Dapr. È possibile visualizzare i log della console eseguendo una query sulla tabella ContainerAppConsoleLogs_CL.

Le colonne specifiche di App contenitore più comunemente usate in ContainerAppConsoleLogs_CL includono:

Log HTTP

App contenitore di Azure può generare log HTTP usando le impostazioni di diagnostica di Monitoraggio di Azure nell’ambiente gestito di App contenitore di Azure.

Usare i log HTTP per esaminare il volume delle richieste, i percorsi, i metodi e i risultati della risposta durante la diagnosi del comportamento dell'API e del traffico Web.

Lo ContainerAppHTTPLogs schema contiene i campi e le descrizioni seguenti:

Log HTTP delle query in Analisi dei log

Usate prima le seguenti query incentrate sul triage, quindi usate gli ulteriori esempi di analisi che seguono.

Visualizzare gli errori HTTP recenti

Usare questa query quando vengono visualizzati tassi di errore elevati nei dashboard, i clienti segnalano errori o si vuole valutare rapidamente ciò che ha esito negativo al momento.

ContainerAppHTTPLogs
| where TimeGenerated > ago(1h)
| where StatusCode >= 400
| project TimeGenerated, ContainerAppName, RevisionName, Method, Path,
  StatusCode, ResponseCodeDetails, RequestDuration, RequestId
| order by TimeGenerated desc
| take 100

Trova richieste lente

Usare questa query quando l'app si sente lenta, si sta analizzando un reclamo di latenza o si vuole verificare una correzione delle prestazioni.

ContainerAppHTTPLogs
| where TimeGenerated > ago(1h)
| where ContainerAppName == "<app-name>"
| top 50 by RequestDuration desc
| project TimeGenerated, Method, Path, StatusCode, RequestDuration,
  ReplicaName, UpstreamRequestAttemptCount, RequestId

Monitorare il volume delle richieste e il tasso di errore per revisione

Usa questa query dopo aver distribuito una nuova revisione e vuoi confermare che funzioni correttamente, oppure quando esegui una distribuzione blue/green e vuoi confrontare due revisioni una accanto all'altra.

ContainerAppHTTPLogs
| where TimeGenerated > ago(6h)
| where ContainerAppName == "<app-name>"
| summarize Requests = count(),
  Errors = countif(StatusCode >= 500),
  ErrorRatePct = round(100.0 * countif(StatusCode >= 500) / count(), 2),
  P95DurationMs = percentile(RequestDuration, 95)
  by RevisionName, bin(TimeGenerated, 5m)
| order by TimeGenerated desc
| render timechart

Traccia una singola richiesta dall'inizio alla fine

Usa questa query quando un cliente segnala una specifica transazione non riuscita e fornisce l'ID della richiesta corrispondente (il valore dell'intestazione x-request-id che ha visualizzato). È necessario trovare la richiesta esatta e i log delle app correlati.

let _requestId = "<request-id>";
ContainerAppHTTPLogs
| where TimeGenerated > ago(24h)
| where RequestId == _requestId
| project TimeGenerated, ContainerAppName, RevisionName, ReplicaName,
  Method, Path, StatusCode, ResponseCodeDetails, ResponseFlags,
  RequestDuration, UpstreamHost, UserAgent, XForwardedFor

Identificare gli endpoint con errori principali

Utilizza questa query quando visualizzi molti errori ma non sai da dove iniziare. Questa query consente di individuare i percorsi responsabili della maggior parte degli errori, in modo da poter classificare in ordine di priorità le correzioni in base all'impatto.

ContainerAppHTTPLogs
| where TimeGenerated > ago(24h)
| where StatusCode >= 400
| summarize Errors = count(),
  DistinctClientIPs = dcount(XForwardedFor),
  SampleStatusCodes = make_set(StatusCode, 5),
  ExampleDetails = take_any(ResponseCodeDetails)
  by ContainerAppName, Method, Path
| order by Errors desc
| take 20

Esaminare i record di log HTTP recenti

Usare questa query per esaminare i record di log HTTP recenti:

ContainerAppHTTPLogs
| where TimeGenerated > ago(2h)
| project TimeGenerated, Method, Path, StatusCode, ContainerAppName, EnvironmentName
| order by TimeGenerated desc
| take 100

Usare gli esempi seguenti per scenari comuni di analisi dei log HTTP.

Distribuzione del codice di stato

ContainerAppHTTPLogs
| where TimeGenerated > ago(24h)
| summarize Count = count() by toint(StatusCode)
| order by Count desc

Visualizzazione incentrata sugli errori (4xx/5xx)

ContainerAppHTTPLogs
| where TimeGenerated > ago(2h)
| extend StatusCodeInt = toint(StatusCode)
| where StatusCodeInt >= 400
| project
    Time=TimeGenerated,
    StatusCode=StatusCodeInt,
    Method,
    Path,
    Details=ResponseCodeDetails,
    EnvName=EnvironmentName,
    AppName=ContainerAppName,
    Revision=RevisionName
| top 100 by Time desc

Latenza (P50/P95/P99) per app e percorso

ContainerAppHTTPLogs
| where TimeGenerated > ago(2h)
| summarize
    Requests = count(),
    P50 = percentile(RequestDuration, 50),
    P95 = percentile(RequestDuration, 95),
    P99 = percentile(RequestDuration, 99)
  by ContainerAppName, Path
| order by P95 desc

Eseguire query sui log con Log Analytics

Log Analytics è uno strumento nel portale di Azure che è possibile usare per visualizzare e analizzare i dati di log. Usando Log Analytics, è possibile scrivere query Kusto e quindi ordinare, filtrare e visualizzare i risultati nei grafici per individuare le tendenze e identificare i problemi. È possibile lavorare in modo interattivo con i risultati della query o usarli con altre funzionalità, ad esempio avvisi, dashboard e cartelle di lavoro.

Portale di Azure

Avvia Log Analytics da Log nel menu laterale della pagina dell'app contenitore. È anche possibile avviare Log Analytics da Monitor > Logs.

Eseguire query sui log usando le tabelle elencate nella categoria Log personalizzati nella scheda Tabelle . Le tabelle in questa categoria sono ContainerAppSystemLogs_CL e ContainerAppConsoleLogs_CL.

Nella query Kusto seguente vengono visualizzate le voci di log della console per l'app contenitore denominata album-api.

ContainerAppConsoleLogs_CL
| where ContainerAppName_s == 'album-api'
| project Time=TimeGenerated, AppName=ContainerAppName_s, Revision=RevisionName_s, Container=ContainerName_s, Message=Log_s
| take 100

Nella query Kusto seguente vengono visualizzate le voci di log di sistema per l'app contenitore denominata album-api.

ContainerAppSystemLogs_CL
| where ContainerAppName_s == 'album-api'
| project Time=TimeGenerated, EnvName=EnvironmentName_s, AppName=ContainerAppName_s, Revision=RevisionName_s, Message=Log_s
| take 100

Per ulteriori informazioni su Log Analytics e le query di log, vedere l'esercitazione di Log Analytics.

interfaccia della riga di comando di Azure o PowerShell

È possibile eseguire query sui log di App contenitore usando interfaccia della riga di comando di Azure.

Queste query di esempio di interfaccia della riga di comando di Azure restituiscono una tabella contenente i record di log per l'app contenitore denominata album-api. I parametri dopo l'operatore project specificano le colonne della tabella. La variabile $WORKSPACE_CUSTOMER_ID ha il GUID dell'area di lavoro Log Analytics.

Questo esempio esegue una query sulla tabella ContainerAppConsoleLogs_CL:

az monitor log-analytics query --workspace $WORKSPACE_CUSTOMER_ID --analytics-query "ContainerAppConsoleLogs_CL | where ContainerAppName_s == 'album-api' | project Time=TimeGenerated, AppName=ContainerAppName_s, Revision=RevisionName_s, Container=ContainerName_s, Message=Log_s, LogLevel_s | take 5" --out table

$queryResults = Invoke-AzOperationalInsightsQuery -WorkspaceId $WORKSPACE_CUSTOMER_ID -Query "ContainerAppConsoleLogs_CL | where ContainerAppName_s == 'album-api' | project Time=TimeGenerated, AppName=ContainerAppName_s, Revision=RevisionName_s, Container=ContainerName_s, Message=Log_s, LogLevel_s | take 5"
$queryResults.Results

Questo esempio esegue una query sulla tabella ContainerAppSystemLogs_CL:

az monitor log-analytics query --workspace $WORKSPACE_CUSTOMER_ID --analytics-query "ContainerAppSystemLogs_CL | where ContainerAppName_s == 'album-api' | project Time=TimeGenerated, AppName=ContainerAppName_s, Revision=RevisionName_s, Message=Log_s, LogLevel_s | take 5" --out table

$queryResults = Invoke-AzOperationalInsightsQuery -WorkspaceId $WORKSPACE_CUSTOMER_ID -Query "ContainerAppSystemLogs_CL | where ContainerAppName_s == 'album-api' | project Time=TimeGenerated, AppName=ContainerAppName_s, Revision=RevisionName_s, Message=Log_s, LogLevel_s | take 5"
$queryResults.Results

Passaggi successivi