VAR

Archivia il risultato di un'espressione come variabile denominata, che è quindi possibile passare come argomento ad altre espressioni di misura. Dopo DAX aver calcolato i valori per un'espressione di variabile, tali valori non cambiano, anche se si fa riferimento alla variabile in un'altra espressione.

Sintassi

VAR <name> = <expression>

Parametri

Termine Definizione
name Nome della variabile (identificatore).
I delimitatori non sono supportati. Ad esempio, 'varName' o [varName] genera un errore.
Set di caratteri supportato: a-z, A-Z, 0-9.
0-9 non sono validi come primo carattere.
__ (doppio carattere di sottolineatura) è consentito come prefisso al nome dell'identificatore.
Non sono supportati altri caratteri speciali.
Le parole chiave riservate non sono consentite.
I nomi delle tabelle esistenti non sono consentiti.
Gli spazi vuoti non sono consentiti.
expression Espressione DAX che restituisce un valore scalare o di tabella.

Valore restituito

Variabile denominata contenente il risultato dell'argomento dell'espressione.

Osservazioni

  • Un'espressione passata come argomento a VAR può contenere un'altra dichiarazione di VAR.

  • Quando si fa riferimento a una variabile:

    • Le misure non possono fare riferimento a variabili definite all'esterno dell'espressione di misura, ma possono fare riferimento a variabili di ambito funzionale definite all'interno dell'espressione.
    • Le variabili possono fare riferimento a misure.
    • Le variabili possono fare riferimento a variabili definite in precedenza.
    • Non è possibile fare riferimento alle colonne nelle variabili di tabella usando la sintassi TableName[ColumnName].

  • Per le procedure consigliate quando si usa VAR, vedere Usare le variabili per migliorare le formule DAX.

  • Per altre informazioni sull'uso di VAR all'interno di una query DAX, vedere DAX query.

Esempio

Gli esempi in questo articolo possono essere usati con il modello adventure works DW 2020 di Power BI Desktop di esempio. Per ottenere il modello, vedere DAX modello di esempio.

Per calcolare una percentuale di crescita annuale nell'anno senza usare una variabile, è possibile creare tre misure separate. Questa prima misura calcola La somma dell'importo delle vendite:

Sum of Sales Amount =
SUM ( Sales[Sales Amount] )

Una seconda misura calcola l'importo delle vendite per l'anno precedente:

Sales Amount PreviousYear =
CALCULATE ( [Sum of Sales Amount], SAMEPERIODLASTYEAR ( 'Date'[Date] ) )

È quindi possibile creare una terza misura che combina le altre due misure per calcolare una percentuale di crescita. Si noti che Sum of SalesAmount viene usato in due posizioni: prima di tutto per verificare se esiste una vendita, quindi di nuovo per calcolare una percentuale.

Sum of SalesAmount YoY%: =
IF (
    [Sum of Sales Amount] && [Sales Amount PreviousYear],
    DIVIDE (
        ( [Sum of Sales Amount] - [Sales Amount PreviousYear] ),
        [Sales Amount PreviousYear]
    )
)

Usando una variabile, è possibile creare una singola misura che calcola lo stesso risultato:

YoY% =
VAR Sales =
    SUM ( Sales[Sales Amount] )
VAR SalesLastYear =
    CALCULATE ( SUM ( Sales[Sales Amount] ), SAMEPERIODLASTYEAR ( 'Date'[Date] ) )
RETURN
    IF ( Sales && SalesLastYear, DIVIDE ( Sales - SalesLastYear, SalesLastYear ) )

Usando una variabile, è possibile ottenere lo stesso risultato in modo più leggibile. Poiché il risultato dell'espressione viene archiviato nella variabile, le prestazioni della misura migliorano significativamente perché DAX non lo ricalcola ogni volta che viene usato.

Contenuto correlato

  • Last updated on