Text.FromBinary

Sintassi

Text.FromBinary(binary as nullable binary, optional encoding as nullable number) as nullable text

Informazioni

Decodifica i dati da un valore binario a un valore di testo usando il tipo di codifica specificato.

• binary: dati binari da decodificare.
• encoding: (Facoltativo) Codifica utilizzata per convertire il file binario in testo. Usare TextEncoding.Type per specificare il tipo di codifica. Se questo valore non viene specificato, la funzione tenta di rilevare automaticamente la codifica o esegue il fallback a TextEncoding.Utf8.

Esempio 1

Codificare il testo in formato binario, produrre una stringa Base64 visualizzabile, quindi decodificarla di nuovo in testo.

Utilizzo

let
    originalText = "Testing 1-2-3",

    // Default UTF-8 binary
    binaryData = Text.ToBinary(originalText),

    // Convert binary to viewable Base64 string
    encodedText = Binary.ToText(binaryData, BinaryEncoding.Base64),

    // Decode back to text
    decodedText = Text.FromBinary(binaryData),

    result = [
        OriginalText = originalText,
        BinaryBase64 = encodedText,
        DecodedText = decodedText
    ]
in
    result

Risultato

[
    OriginalText = "Testing 1-2-3",
    BinaryBase64 = "VGVzdGluZyAxLTItMw==",
    DecodedText = "Testing 1-2-3"
]

Esempio 2

Codificare il testo in formato binario con un byte Order Mark (BOM), produrre una stringa esadecimale visualizzabile, quindi decodificarla di nuovo nel testo.

Utilizzo

let
    originalText = "Testing 1-2-3",

    // Convert to binary with BOM
    binaryData = Text.ToBinary(originalText, TextEncoding.Utf16, true),

    // Show binary as hex to demonstrate presence of BOM (fffe)
    binaryAsHex = Binary.ToText(binaryData, BinaryEncoding.Hex),

    // Decode back to text
    decodedText = Text.FromBinary(binaryData, TextEncoding.Utf16),

    // Compare original text and decoded text
    isIdentical = originalText = decodedText,

    result = [
        OriginalText = originalText,
        BinaryHex = binaryAsHex,
        DecodedText = decodedText,
        IsIdentical = isIdentical
    ]
in
    result

Risultato

[
    OriginalText = "Testing 1-2-3",
    BinaryHex = "fffe540065007300740069006e006700200031002d0032002d003300",
    DecodedText = "Testing 1-2-3",
    IsIdentical = true
]