Kjøretidsfunksjoner for X++-gjenspeiling

Denne artikkelen beskriver funksjonene for gjenspeilingskjøring.

classIdGet

Henter den numeriske identifikatoren (klasse-IDen) for klassen som det initialiserte objektet tilhører.

int classIdGet(class object)

Parameters

Return value

Klasse-ID-en for det angitte objektet.

Example

static void classIdGetExample(Args _args)
{
    int i;
    WorkTimeCheck w;

    i = classIdGet(w);
    print "Class ID for object is " + int2Str(i);
}

dimOf

Henter antall indekselementer som er tildelt plass i en X++-matrise.

int dimOf(anytype object)

Parameters

Return value

Hvis verdien for objektparameteren er en matrise, antall elementer i matrisen. ellers 0 (null).

Remarks

DimOf-funksjonen er beregnet for X++-matriser som deklareres som følgende X++ primitive typer:

• boolean
• date
• int
• int64
• real
• utcDateTime

Et eksempel er int iAmounts[6];. Matriser med opplistingsverdier og utvidede datatyper støttes også hvis de til slutt er basert på én av de foregående primitive datatypene (for eksempel int). DimOf-funksjonen godtar ikke matriser av alle X++ primitive typer. Her er matrisetypene som dimOf-funksjonen ikke godtar:

• str
• container
• anytype
• Matriser av klasseobjekter
• Forekomster av matriseklassen

Example

static void JobDimOfArrays(Args _args)
{
    int iAmounts[20], iCounts[];
    ABCModel enumAbcModel[22]; // Enum
    ABCModelType exdtAbcModelType[24]; // Extended data type
    anytype anyThings[26];
    str sNames[28];
    Array myArrayObj; // Class

    info("Start of job.");
    info("--(Next, normal int array, dimOf() accepts it.)");
    info(int2Str(dimOf(iAmounts)));
    info("--(Next, normal enum array, dimOf() accepts it.)");
    info(int2Str(dimOf(enumAbcModel)));
    info("--(Next, normal extended data type array (based on enum), dimOf() accepts it.)");
    info(int2Str(dimOf(exdtAbcModelType)));
    info("--(Next, dynamic int array, dimension not yet set.)");
    info(int2Str(dimOf(iCounts)));
    info("--(Next, dynamic int array, after dimension established.)");

    iCounts[13] = 13;
    info(int2Str(dimOf(iCounts)));
    info(" == == == == == (Next, array types that dimOf() does not support.)");
    info("--(Next, normal anytype array, dimOf() always returns 0.)");
    info(int2Str(dimOf(anyThings)));
    info("--(Next, an instance of class X++ Array, dimOf() always returns 0.)");

    myArrayObj = new Array(Types::Integer);
    myArrayObj.value(1,501);
    info(int2Str(dimOf(myArrayObj)));
    info("--(Next, the lastIndex method provides size information about Array instances.)");
    info(int2Str(myArrayObj.lastIndex()));
    info("--(Next, normal str array, dimOf() does not accept it, job is halted.)");
    info(int2Str(dimOf(sNames)));
    info("End of job.");

}
/************  Actual Infolog output
Message (11:10:06 am)
Start of job.
--(Next, normal int array, dimOf() accepts it.)
20
--(Next, normal enum array, dimOf() accepts it.)
22
--(Next, normal extended data type array (based on enum), dimOf() accepts it.)
24
--(Next, dynamic int array, dimension not yet set.)
0
--(Next, dynamic int array, after dimension established.)
16
== == == == == (Next, array types that dimOf() does not support.)
--(Next, normal anytype array, dimOf() always returns 0.)
0
--(Next, an instance of class X++ Array, dimOf() always returns 0.)
0
--(Next, the lastIndex method provides size information about Array instances.)
1
--(Next, normal str array, dimOf() does not accept it, job is halted.)
Error executing code: Illegal operation on this type of array. (C)JobsJobDimOfArrays - line 41
************/
/***********  Pop-up error dialog box
"Internal error number 25 in script."
This error is caused by the code line...
info(int2Str(dimOf(iCounts)));
...before iCounts was assigned at any index.
***********/

fieldId2Name

Henter en streng som representerer navnet på feltet du angir ved hjelp av et tabell-ID-nummer og et felt-ID-nummer.

str fieldId2Name(int tableid, int fieldid)

Parameters

Return value

Navnet på feltet.

Remarks

Hvis du vil returnere en utskrivbar versjon av feltnavnet, bruker du fieldId2PName-funksjonen .

Example

Følgende eksempel angir fn til navnet på feltet i kundetabellen (CustGroup) som har en felt-ID på 7.

static void fieldId2NameExample(Args _arg)
{
    str fn;
    fn = fieldId2Name(tableName2Id("Customer"),7);
}

fieldId2PName

Henter det utskrivbare navnet på feltet du angir ved hjelp av et tabell-ID-nummer og et felt-ID-nummer.

str fieldId2PName(int tableid, int fieldid)

Parameters

Return value

Navnet på feltet.

Example

static void fieldId2PNameExample(Args _arg)
{
    str name;
    tableid _tableId;
    fieldid _fieldid;

    _tableId = tableName2Id("Address");
    _fieldId = fieldName2Id(_tableId, "Name");
    name = fieldId2PName(_tableId, _fieldid);
    print name;
}

fieldName2Id

Henter felt-ID-en for tabellfeltet du angir ved hjelp av et tabell-ID-nummer og et felt-ID-nummer.

int fieldName2Id(int tableid, str fieldname)

Parameters

Return value

ID-en for feltet som tabell-ID - og feltnavnparameterne angir.

Example

static void fieldName2IdExample(Args _arg)
{
    int id;

    id = fieldName2Id(tableName2Id("Address"), "Name");
    // Returns 6. Name is the 6th field in the Address table.
    print id;
}

indexId2Name

Henter navnet på en indeks.

str indexId2Name(int tableid, int indexid)

Parameters

Return value

Navnet på indeksen.

Example

static void indexId2NameExample(Args _arg)
{
    str s;
    tableid id;
    indexid idx;

    id  = tableName2Id("Address");
    idx = indexName2Id(id, "AddrIdx");
    s = indexId2Name(id, idx);
    print "The result of calling indexId2Name is " + s;
}

indexName2Id

Henter ID-en for en indeks.

int indexName2Id(int tableid, str indexname)

Parameters

Return value

ID-en for indeksen.

Example

static void indexName2IdExample(Args _arg)
{
    indexid idx;
    tableid id;

    id  = tableName2Id("Address");
    idx = indexName2Id(id, "AddrIdx");
    print "Index ID for index name AddrIdx of table Address is " + int2Str(idx);
}

tableId2Name

Henter en streng som inneholder navnet på en tabell.

str tableId2Name(int _tableid)

Parameters

Return value

Navnet på tabellen.

Example

static void tableId2NameExample(Args _arg)
{
    str s;
    tableid id;

    // Get the ID for table name Address.
    id = tableName2Id("Address");
    print "ID for table name Address is " + int2Str(id);

    // Get the name from the table ID.
    s = tableId2Name(id);
    print "Name for table ID " + int2Str(id) + " is " + s;

    // Get the printable name from the table ID.
    s = tableId2PName(id);
    print "Printable name for table ID " + int2Str(id) + " is " + s;
}

tableId2PName

Henter en streng som inneholder navnet (etiketten) på en tabell som kan skrives ut.

str tableId2PName(int _fieldid)

Parameters

Return value

Etiketten for tabellen.

Example

static void tableId2NameExample(Args _arg)
{
    str s;
    tableid id;

    // Get the ID for table name Address.
    id = tableName2Id("Address");
    print "ID for table name Address is " + int2Str(id);

    // Get the name from the table ID.
    s = tableId2Name(id);
    print "Name for table ID " + int2Str(id) + " is " + s;

    // Get the printable name from the table ID.
    s = tableId2PName(id);
    print "Printable name for table ID " + int2Str(id) + " is " + s;
}

tableName2Id

Henter ID-en for en tabell.

int tableName2Id(str _name)

Parameters

Return value

ID-en for tabellen.

Example

static void tableName2IdExample(Args _arg)
{
    str s;
    tableid id;

    // Get the ID for the Address table name.
    id = tableName2Id("Address");
    print "ID for the Address table name is " + int2Str(id);

    // Get the name from the table ID.
    s = tableId2Name(id);
    print "Name for table ID " + int2Str(id) + " is " + s;

    // Get the printable name from the table ID.
    s = tableId2PName(id);
    print "Printable name for table ID " + int2Str(id) + " is " + s;
}

typeOf

Henter typen til et element.

enum typeOf(anytype _object)

Parameters

Return value

En type systemopplistingsverdi.

Example

Eksemplet nedenfor tester om det første elementet i en beholder, c, er en annen beholder som inneholder ett heltall.

if(typeof(conpeek(c, 1)) != Types::Container ||
conlen(conpeek(c, 1)) != 1 ||
typeof(conpeek(conpeek(c, 1), 1)) != Types::Integer)
{
    // More code.
}