Método Report.Line (Access)

O método Line desenha linhas e retângulos em um objeto Report quando o evento Print ocorre.

Sintaxe

mais simples. Linha (Etapa (x1, y1) - Etapa (x2, y2), Cor, BF)

expressão Obrigatório. Uma variável que representa um objeto Report . Uma expressão que retorna um dos objetos na lista Aplica-se a.

Parâmetros

Nome Tipo de dados Descrição
Etapa Palavra-chave Indica que as coordenadas do ponto inicial são relativas à posição gráfica atual fornecida pelas configurações atuais para as propriedades CurrentX e CurrentY do argumento Object .
X1, Y1 Single Indica as coordenadas do ponto inicial para a linha ou retângulo. As propriedades Scale (ScaleMode, ScaleLeft, ScaleTop, ScaleHeight e ScaleWidth) do objeto Report especificado pelo argumento Object determinam a unidade de medida usada. Se esse argumento for omitido, a linha começará na posição indicada pelas propriedades CurrentX e CurrentY .
X2, Y2 Single Obrigatório. Indica as coordenadas do ponto final para a linha ou retângulo. Verifique se o ponto inicial e o ponto final estão separados por um hífen ( - ).
Color Long Indica a cor RGB (vermelho-verde-azul) usada para desenhar a linha. Se esse argumento for omitido, o valor da propriedade ForeColor é usado. Você também pode usar a função RGB ou QBColor função para especificar a cor.
B Uma opção que cria um retângulo usando as coordenadas como extremidades opostas do retângulo.
S F não pode ser usado sem B. Se a opção B for usada, a opção F especificará que o retângulo é preenchido com a mesma cor usada para desenhar o retângulo. Se B for usada sem F, o retângulo será preenchido com a cor especificada pelas configurações atuais das propriedades FillColor e BackStyle. O valor padrão da propriedadeBackStyle é Normal para retângulos e linhas.

Comentários

Use esse método somente em um procedimento de evento ou em uma macro especificada pela propriedade de evento OnPrint ou OnFormat de uma seção de relatório, ou pela propriedade de evento OnPage de um relatório.

Para conectar duas linhas desenhadas, certifique-se de que uma linha começa no ponto final da linha anterior.

A largura da linha desenhada depende da configuração da propriedade DrawWidth . A maneira como uma linha ou retângulo é desenhado no plano de fundo depende das configurações das propriedades DrawMode e DrawStyle .

Quando você aplica o método Line , as propriedades CurrentX e CurrentY são redefinidas para o ponto final especificado pelos argumentos x2 e y2 .

Exemplo

O exemplo a seguir usa o método Line para desenhar um retângulo vermelho cinco pixels dentro da borda de um relatório chamado EmployeeReport. A função RGB é utilizada para tornar a linha vermelha.

Para experimentar este exemplo no Microsoft Access, crie um novo relatório chamado EmployeeReport. Cole o código a seguir na seção Declarações do módulo do relatório e alterne para Visualização de Impressão.

Private Sub Detail_Print(Cancel As Integer, PrintCount As Integer) 
    ' Call the Drawline procedure 
    DrawLine 
End Sub 
 
Sub DrawLine() 
    Dim rpt As Report, lngColor As Long 
    Dim sngTop As Single, sngLeft As Single 
    Dim sngWidth As Single, sngHeight As Single 
 
    Set rpt = Reports!EmployeeReport 
    ' Set scale to pixels. 
    rpt.ScaleMode = 3 
    ' Top inside edge. 
    sngTop = rpt.ScaleTop + 5 
    ' Left inside edge. 
    sngLeft = rpt.ScaleLeft + 5 
    ' Width inside edge. 
    sngWidth = rpt.ScaleWidth - 10 
    ' Height inside edge. 
    sngHeight = rpt.ScaleHeight - 10 
    ' Make color red. 
    lngColor = RGB(255,0,0) 
    ' Draw line as a box. 
    rpt.Line(sngTop, sngLeft) - (sngWidth, sngHeight), lngColor, B 
End Sub

Suporte e comentários

Tem dúvidas ou quer enviar comentários sobre o VBA para Office ou sobre esta documentação? Confira Suporte e comentários sobre o VBA para Office a fim de obter orientação sobre as maneiras pelas quais você pode receber suporte e fornecer comentários.

  • Last updated on